Rewrite 2 repeating With-blocks

Question

Got the following piece of code:

          If boolFlag Then
              With offer.Person1
                entity.Birthdate = .BirthDate

                entity.FirstName = .FirstGivenName
                entity.LastName = .FamilyName

                entity.Street = .StreetName
                entity.HousNr = .HouseNumberIdentifier
                entity.BoxNr = .BoxNumberIdentifier
                entity.PostalCode = .PostalCode
                entity.Municipality = .CityName
            End With
        Else
            With offer.Person2
                entity.Birthdate = .BirthDate

                entity.FirstName = .FirstGivenName
                entity.LastName = .FamilyName

                entity.Street = .StreetName
                entity.HousNr = .HouseNumberIdentifier
                entity.BoxNr = .BoxNumberIdentifier
                entity.PostalCode = .PostalCode
                entity.Municipality = .CityName
            End With
        End If

Objects Person1 and Person2 are of different types, and those types do not share a common Interface / class. (And that can't be changed)

How do I avoid the duplicate code inside the With-blocks?

Answer 1

Options:

1. Change the original code base (best option, what should happen)
2. Inherit your own objects from the originals and attach an interface (given your scenario, this is the option to go with)
3. Use static helper methods ( you can abstract and decorate the routine to make it better in your core programming, but the code will still be duplicated.

These items are listed in order of how you should approach the solution. I hope this helps.

Answer 2

Unless you can make them share a common interface, it is not desirable to eliminate the code duplication -- best case (vb.net late binding on Object), trades your code size for the compilers. Doing the work yourself, simply means more code for you.

That said, where the code duplication is, is something you might want to control. Extract each assignment out into a similarly named method, and call the appropriate one.

Sub UpdateEntityFromPerson(ByVal entity as Entity, ByVal person as Person1)
    With person
        entity.Birthdate = .BirthDate

        entity.FirstName = .FirstGivenName
        entity.LastName = .FamilyName

        entity.Street = .StreetName
        entity.HousNr = .HouseNumberIdentifier
        entity.BoxNr = .BoxNumberIdentifier
        entity.PostalCode = .PostalCode
        entity.Municipality = .CityName
    End With
End Sub

Sub UpdateEntityFromPerson(ByVal entity as Entity, ByVal person as Person2)
    With Person
        entity.Birthdate = .BirthDate

        entity.FirstName = .FirstGivenName
        entity.LastName = .FamilyName

        entity.Street = .StreetName
        entity.HousNr = .HouseNumberIdentifier
        entity.BoxNr = .BoxNumberIdentifier
        entity.PostalCode = .PostalCode
        entity.Municipality = .CityName
    End With
End Sub

        If boolFlag Then
            UpdateEntityFromPerson(entity, offer.person1)
        Else
            UpdateEntityFromPerson(entity, offer.person2)
        End If

All of the code is still duplicated, but it type safe, clear, and easy to use and understand. Of course, the best thing to do is probably to have an entity constructor that takes one or the other, or a builder that does so, but that depends upon other factors, outside your snippet...

Answer 3

One possible solution could look like this, where "[yourEntityType]" is the type of "entity" in your code:

Public Class CopyHelper(Of T As Class)
        Public Shared Sub UpdateEntity(person As T, entity As [yourEntityType])

            Dim birthDateProperty As System.Reflection.PropertyInfo = person.GetType().GetProperty("BirthDate")

            If Not IsNothing(birthDateProperty) Then
                entity.Birthdate = birthDateProperty.GetValue(person, Nothing)
            End If

            Dim firstGivenNameProperty As System.Reflection.PropertyInfo = person.GetType().GetProperty("FirstGivenName")
            If Not IsNothing(firstGivenNameProperty) Then
                entity.FirstName = firstGivenNameProperty.GetValue(person, Nothing)
            End If

            ...

        End Sub
End Class

and finally your code will look as below

If boolFlag Then
    CopyHelper(Of Person1).UpdateEntity(offer.Person1, entity)
Else
    CopyHelper(Of Person2).UpdateEntity(offer.Person2, entity)
End If

Hope this helps!