Defining a zip code string

Question

I'm following this

let StringOfLengthConstructor<'c> (input:string, length:int, defaultConstructor:string->'c) =
    match input with
    | null -> None
    | x when x.Length = length -> Some(defaultConstructor(input))
    | _ -> None
type String3 = | String3 of string
let String3 input = StringOfLengthConstructor<String3>(input, 3, String3)    
type String4 = | String4 of string
let String4 input= StringOfLengthConstructor<String4>(input, 4, String4)

type String5 = | String5 of string
let String5 input = StringOfLengthConstructor<String5>(input, 5, String5)
type String6 = | String6 of string
let String6 input = StringOfLengthConstructor<String6>(input,6, String6)

and am trying to make more of these with hopefully less repetition. Can this be done without having to repeat type String3 =| String3 of string followed by this?

let String3 input = StringOfLengthConstructor<String3>(input, 3, String3)  

See all the repetition? For the purpose of defining a zip code, a US zip code could be defined as

type ZipCode = | Us of String5

or

type ZipCode = | Us of String5*(String4 option) | Canadian of String3*String3

Answer 1

The solution can be made cleaner by re-arranging the order of the arguments and using pointfree style.

let StringOfLengthConstructor<'c> (length : int) (defaultConstructor : string -> 'c) (input : string) =
    match input with
    | x when x <> null && x.Length = length -> Some (defaultConstructor input)
    | _ -> None

type String3 = String3 of string
let String3 = StringOfLengthConstructor 3 String3

However, I don't think that String5 * (String4 option) is a good definition of a zip code. The code should be validating on more than just the string length.

Answer 2

Concerning the smart constructor thing I mentioned - I would implement the types like this:

module SafeLengthStrings =

   let private assertLength (length : int) (input : string) : string =
       if input.Length <> length 
       then failwith (sprintf "expected string of length %d but got %s" length input)
       else input

   type String3 = private Str3 of string
   let string3 : (string -> String3) =
       assertLength 3 >> Str3

This way you cannot construct malformed String3 instances at runtime (minus Reflection of course)