MongoDB Perl Wrapper

Question

I'm trying to create a custom "mongodb perl wrapper". I created the following perl module, which local on my machine runs. My questions to the community are:

• Would you create the module different?
• Do you have improvements or adaptations to create the module better?

Code:

package MyMongo;

use strict;
use Exporter;
use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
use MongoDB;

$VERSION     = 1.00;
@ISA         = qw(Exporter);
@EXPORT      = qw();
@EXPORT_OK   = qw();
%EXPORT_TAGS = ( DEFAULT => [qw()],
                 Both    => [qw()]);

sub new {
    my ($class, $args) = @_;
    my $self = {
        host     => $args->{host} || 'localhost',       
        port     => $args->{port} || '27017',
        database => $args->{database} || '',
        connection => $class->_set_connection(),
    };
    return bless $self, $class;
}

sub _set_connection {
    my $self = shift;
    my $client = MongoDB->connect('mongodb://localhost');
    return $client;
}

sub get_database_names {
    # Lists all databases on the mongo server
    my $self = shift;
    return  $self->{connection}->database_names;
}

sub get_database {
    # Returns a MongoDB::Database instance for database with the given $name
    my ($self, $dbname) = @_;
    return $self->{connection}->get_database($dbname);
}

sub authenticate {
    my ($self, $args) = @_;
    $self = {
        dbname => $args->{dbname},
        user => $args->{user},
        password => $args->{password}
    };
    $self->{connection}->authenticate($self->{dbname}, $self->{user}, $self->{password});
}
1;

Answer 1

I'm the lead engineer for the MongoDB Perl driver with a couple of thoughts for you:

• you're using 'authenticate', which is for a very old version of the driver which is not recommended for use. In the v1.x series, you should provide username/password in the URI or in MongoClient parameters.
• Most of the value of this module seems to be setting parameters and calling connect. I would suggest doing that with a function, not a module and then just using the resulting MongoDB::MongoClient object directly.

Answer 2

Please check comments in the code,

# package using block, convenient but not mandatory
package MyMongo {

    use strict;
    # as it seems you just need import() from Exporter module
    use Exporter 'import';
    use MongoDB;

    # use vars qw(..) works for older perl, but since 5.6 "our" is preferred
    our $VERSION     = 1.00;
    # it seems you don't actually want to be child of Exporter, so no parent class
    our @ISA         = qw();
    our @EXPORT      = qw();
    our @EXPORT_OK   = qw();
    our %EXPORT_TAGS = ( DEFAULT => [qw()],
                     Both    => [qw()]);

    sub new {
        my ($class, $args) = @_;
        my %defaults = (
            host     => 'localhost',       
            port     => '27017',
            database => '',
        );
        my $self = bless({ %defaults, %$args }, $class);

        $self->{connection} = $self->_set_connection();
        return $self;
    }

    # ...
}

1;

More suggestions in perldoc Exporter