3
\$\begingroup\$

Problem statement

I've tried to solve the following Euler problem in a very straight-forward way, ideally avoiding recursion if possible and writing it in a functional style.

What is the greatest product of four adjacent numbers in the same direction (up, down, left, right, or diagonally) in the 20×20 grid?

The full problem statement can be found here.

Implementation

Data

problem11.txt

08 02 22 97 38 15 00 40 00 75 04 05 07 78 52 12 50 77 91 08
49 49 99 40 17 81 18 57 60 87 17 40 98 43 69 48 04 56 62 00
81 49 31 73 55 79 14 29 93 71 40 67 53 88 30 03 49 13 36 65
52 70 95 23 04 60 11 42 69 24 68 56 01 32 56 71 37 02 36 91
22 31 16 71 51 67 63 89 41 92 36 54 22 40 40 28 66 33 13 80
24 47 32 60 99 03 45 02 44 75 33 53 78 36 84 20 35 17 12 50
32 98 81 28 64 23 67 10 26 38 40 67 59 54 70 66 18 38 64 70
67 26 20 68 02 62 12 20 95 63 94 39 63 08 40 91 66 49 94 21
24 55 58 05 66 73 99 26 97 17 78 78 96 83 14 88 34 89 63 72
21 36 23 09 75 00 76 44 20 45 35 14 00 61 33 97 34 31 33 95
78 17 53 28 22 75 31 67 15 94 03 80 04 62 16 14 09 53 56 92
16 39 05 42 96 35 31 47 55 58 88 24 00 17 54 24 36 29 85 57
86 56 00 48 35 71 89 07 05 44 44 37 44 60 21 58 51 54 17 58
19 80 81 68 05 94 47 69 28 73 92 13 86 52 17 77 04 89 55 40
04 52 08 83 97 35 99 16 07 97 57 32 16 26 26 79 33 27 98 66
88 36 68 87 57 62 20 72 03 46 33 67 46 55 12 32 63 93 53 69
04 42 16 73 38 25 39 11 24 94 72 18 08 46 29 32 40 62 76 36
20 69 36 41 72 30 23 88 34 62 99 69 82 67 59 85 74 04 36 16
20 73 35 29 78 31 90 01 74 31 49 71 48 86 81 16 23 57 05 54
01 70 54 71 83 51 54 69 16 92 33 48 61 43 52 01 89 19 67 48

Code

My program structure is based on calculating the indices of 4-tuples that can be found diagonally, anti-diagonally, horizontally and vertically. I obtain this by reading the input grid into a single vector, then doing some magic to get respectively the diagonal, anti-diagonal, horizontal and vertical lines, and then I partition each line into segments of size 4 with an offset of 1.

problems/problem11.clj

(ns project-euler.problems.problem11
  (:require [clojure.java.io :as io]
            [clojure.string :as str]
            [clojure.math.numeric-tower :as math]))

(defn- read-grid []
  (with-open [rdr (io/reader (io/resource "problem11.txt"))]
    (->> (line-seq rdr)
         (str/join " ")
         (#(str/split % #" "))
         (map (comp read-string #(str "10r" %)))
         vec)))

(defrecord coordinate [x y])

(defn- to-coordinate [size n]
  (coordinate. (- n (* size (int (math/floor (/ n size)))))
               (int (math/floor (/ n size)))))

(defn- mirror-horizontal [size coord]
  (coordinate. (- (dec size) (:x coord))
               (:y coord)))

(defn- to-index [size coord]
  (+ (* size (:y coord)) (:x coord)))

(defn- incrementing-by? [n s]
  (apply = n (map - (rest s) s)))

(defn- diagonal-indices-in-grid [size total n]
  (->> (range 0 total)
       (group-by #(mod % (inc size)))
       vals
       (mapcat (partial partition n 1))
       (filter #(incrementing-by? 1 (map (comp :x (partial to-coordinate size)) %)))))

(defn- anti-diagonal-indices-in-grid [size total n]
  (->> (range 0 total)
       (group-by #(mod % (inc size)))
       vals
       (map (partial map #(to-index size (mirror-horizontal size (to-coordinate size %)))))
       (mapcat (partial partition n 1))
       (filter #(incrementing-by? -1 (map (comp :x (partial to-coordinate size)) %)))))

(defn- horizontal-indices-in-grid [size total n]
  (->> (range 0 total)
       (group-by #(:y (to-coordinate size %)))
       vals
       (mapcat (partial partition n 1))))

(defn- vertical-indices-in-grid [size total n]
  (->> (range 0 total)
       (group-by #(:x (to-coordinate size %)))
       vals
       (mapcat (partial partition n 1))))

(defn largest-product-in-grid [n]
  {:pre [(pos? n)]}
  (let [grid (read-grid)
        total (count grid)
        size (int (math/sqrt total))]
    (->> (concat (diagonal-indices-in-grid size total n)
                 (anti-diagonal-indices-in-grid size total n)
                 (horizontal-indices-in-grid size total n)
                 (vertical-indices-in-grid size total n))
         (map (partial map (partial nth grid)))
         (map (partial reduce *))
         (apply max))))

(println (largest-product-in-grid 4))

I must admit that the code got a little bit more complicated than I thought it would be.

\$\endgroup\$
1
\$\begingroup\$

I must admit that the code got a little bit more complicated than I thought it would be.

I agree. Since the problem deals with a grid, to me it's a pretty good fit for a i . j matrix type of solution. This is a great traditional imperative type of problem. It can be made more functional I suppose, but IMO it's important to tailor the solution to the problem, not the language, and clojure actually is a good fit for it either way.

If we think of the first position where we begin the sum as starting from the top and moving rightwards and downwards (never leftwards and upwards), then for each case (horizontal, vertical, diag left, diag right) we have a clear picture of where the first position can be, and where it can't be. So from the beginning, for each of the four finite cases, we know, given the grid width, height, and length of the adjacent numbers, which rows are valid/invalid, and which columns are valid/invalid.

  • For the vertical case, the starting position can't be on any of the last three rows -- it can be in any column, but must be on row 0-16 (not 17-19). From the start, we fix the column and add the next 3 rows.

  • For horizontal, it can't be on any of the last three columns -- it can be in any row, but must be on column 0-16 (not 17-19). From the start, we fix the row and add the next 3 columns.

  • For the "backslash" diagonal, it can't be on either the last three columns, or the last three rows. From the start, we increase the row and column, 3 times.

  • For the "slash" diagonal, it can't be on either the first three columns, or the last three rows. From the start, we increase the row and decrease the column, 3 times.

For each position, and for each of the 4 cases, we test whether the current position is a valid position, and if it is, add up the elements at the four positions.

The below answer is generalized, so that it can be used on any size grid, with any length. I hope it's okay to post it here to give an idea.

(def width 20)
(def height 20)
(def len 4)

(defn row-col-to-index
  [row col]
  (+ (* row width) col))

(defn value-at [v row col]
  (get v (row-col-to-index row col)))

(defn answer []
  (let [rowmax (- height len)
        colmin (dec len)
        colmax (- width len)
        loopvec (range len)]
    (apply max
      (flatten
        (for [row (range height)
              col (range width)]
          [(if (> row rowmax) 0
            (reduce * (for [i loopvec]
                        (value-at grid (+ row i) col))))
          (if (> col colmax) 0
            (reduce * (for [i loopvec]
                        (value-at grid row (+ col i)))))
          (if (or (> row rowmax) (> col colmax)) 0
            (reduce * (for [i loopvec]
                        (value-at grid (+ row i) (+ col i)))))
          (if (or (> row rowmax) (< col colmin)) 0
            (reduce * (for [i loopvec]
                        (value-at grid (+ row i) (- col i)))))])))))
\$\endgroup\$
0
\$\begingroup\$

Unless I was are concerned about speed, I'd prefer to tackle this using the sequence library upon a vector of rows.

If we take the first row (removing redundant leading zeros):

(def row [8 2 22 97 38 15 0 40 0 75 4 5 7 78 52 12 50 77 91 8])

... then the number we want is ...

(->> row
     (partition 4 1)
     (map #(apply * %))
     (apply max))
;4204200

If we have the whole array as a vector of vectors, we can transpose it with

(defn transpose [vss]
  (apply mapv vector vss))

For example

(transpose [[1 2] [3 4]])
;[[1 3] [2 4]]

That deals with rows and columns. You can play similar tricks to get the diagonals, with liberal use of rest and reverse.

\$\endgroup\$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.